Wikilivres

Fichier:Hyperbolic orbit.gif

Hyperbolic_orbit.gif ‎(300 × 300 pixels, taille du fichier : 12 kio, type MIME : image/gif, en boucle, 90 trames, 4,2 s)

 
Cette infographie a été créée avec POV-Ray.
a Semimajor axis
rp Periapsis' Radius
υ∞ Divergence angle

Description

Description Animation showing the motion of a small body (green) in an hyperbolic orbit around a much more massive body (blue).
Date
Source Own work. Rendered with PovRay-3.0, animated with gifsicle.
Auteur Brandir
Autorisation
(Réutilisation de ce fichier)		 Brandir put it under the GFCL and the CC-BY-SA

Conditions d’utilisation

Moi, en tant que détenteur des droits d’auteur sur cette œuvre, je la publie sous les licences suivantes :
GNU head Vous avez la permission de copier, distribuer et modifier ce document selon les termes de la GNU Free Documentation License version 1.2 ou toute version ultérieure publiée par la Free Software Foundation, sans sections inaltérables, sans texte de première page de couverture et sans texte de dernière page de couverture. Un exemplaire de la licence est inclus dans la section intitulée GNU Free Documentation License.
w:fr:Creative Commons
paternité partage à l’identique 		Ce fichier est disponible selon les termes de la licence Creative Commons Attribution – Partage dans les Mêmes Conditions 3.0 (non transposée).
Vous êtes libre :
  • de partager – de copier, distribuer et transmettre cette œuvre
  • d’adapter – de modifier cette œuvre
Sous les conditions suivantes :
  • paternité – Vous devez donner les informations appropriées concernant l'auteur, fournir un lien vers la licence et indiquer si des modifications ont été faites. Vous pouvez faire cela par tout moyen raisonnable, mais en aucune façon suggérant que l’auteur vous soutient ou approuve l’utilisation que vous en faites.
  • partage à l’identique – Si vous modifiez, transformez, ou vous basez sur cette œuvre, vous devez distribuer votre contribution sous la même licence ou une licence compatible avec celle de l’original.
Ce bandeau de licence a été ajouté à ce fichier dans le cadre de la procédure de mise à jour des licences des images sous GFDL.
w:fr:Creative Commons
paternité partage à l’identique
Ce fichier est disponible selon les termes de la licence Creative Commons Attribution – Partage dans les Mêmes Conditions 2.5 Espagne.
Vous êtes libre :
  • de partager – de copier, distribuer et transmettre cette œuvre
  • d’adapter – de modifier cette œuvre
Sous les conditions suivantes :
  • paternité – Vous devez donner les informations appropriées concernant l'auteur, fournir un lien vers la licence et indiquer si des modifications ont été faites. Vous pouvez faire cela par tout moyen raisonnable, mais en aucune façon suggérant que l’auteur vous soutient ou approuve l’utilisation que vous en faites.
  • partage à l’identique – Si vous modifiez, transformez, ou vous basez sur cette œuvre, vous devez distribuer votre contribution sous la même licence ou une licence compatible avec celle de l’original.
Vous pouvez choisir l’une de ces licences.

POV-Ray Scene description

POV-ray image description: 

 /*
 --------------------------
 Hyperbolic Orbit Animation
 --------------------------
 Created 7 Mar. 2006
 */
     
 #include "colors.inc"
 
 //Orbit Definition
 #declare OrbitA=30;
 #declare OrbitE=1.38;
 
 //Scene Constants
 #declare EarthRadius=6.356;
 #declare SatRadius=1.2;
 #declare OrbitWidth=0.5;
 #declare LineWidth=0.5/3;
 #declare Crosslength=1.5;
 #declare Textscale=9;
 #declare TextColor=rgb<0,0,0>;
 #declare xinit=-35;
 
 //Variables
 #declare Minit=OrbitE*sinh(acosh(-(xinit/OrbitA-OrbitE)))-acosh(-(xinit/OrbitA-OrbitE));
 #declare M=Minit-2*clock*Minit;
 #declare PI=3.14159265359;
 #declare Angleinf=180-acos(-1/OrbitE)*(180/PI);
 
 //Anomaly Determination - Solves the equation M=e*sinh(H)-H by the iterative method
 #declare Index=0;
 #declare prevAnomaly=0;
 #declare Anomaly=0;
 #while (Index<30)
     #declare Anomaly=asinh((M+prevAnomaly)/OrbitE);
     #declare prevAnomaly=Anomaly;
     #declare Index=Index+1;
 #end
 
 //General settings
 global_settings{
     ambient_light 1
     }
 
 light_source { <-50, 0, -70> color White }
 
 camera {
   orthographic
   location <-10, 0, -10>
   look_at  <-10, 0,  0>
   up <0,100,0>
   right <100,0,0>
 }
 
 
 plane { <0, 0, 1>, 8
     pigment {White}
     finish{ambient 1 brilliance 0}
 }
 
 
 //Earth
 sphere {
     <0, 0, 0>, EarthRadius
     pigment { Blue }
     finish{ ambient 0.3 brilliance 1.2 diffuse 0.8}
 }
 
 
 //Orbit
 intersection{
     box{
         <-100,-100,-OrbitWidth>, <100,100,OrbitWidth> 
     }
     quadric{
         <1/(OrbitA*OrbitA),-1/(OrbitA*OrbitA*(OrbitE*OrbitE-1)),0>,<0,0,0>,<2*OrbitE/OrbitA,0,0>,OrbitE*OrbitE-1
         translate x*OrbitWidth/2
     }
     quadric{
         <-1/(OrbitA*OrbitA),1/(OrbitA*OrbitA*(OrbitE*OrbitE-1)),0>,<0,0,0>,<-2*OrbitE/OrbitA,0,0>,1-OrbitE*OrbitE
         translate -x*OrbitWidth/2
     }
     pigment{ rgb<0.8,0,0> }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate 2.2*y
     no_shadow
 }
 
 
 //Satellite
 sphere {
     <0, 0, -10>, SatRadius
     pigment { SeaGreen }
     finish{ ambient 1 brilliance 0 diffuse 0}
     no_shadow
     translate <-OrbitA*(OrbitE-cosh(Anomaly)),OrbitA*sqrt(OrbitE*OrbitE-1)*sinh(Anomaly),0>
 }
 
 //Lines
 #declare crossBars=
 object{
     union{
         box{
             <-LineWidth,-Crosslength,-LineWidth-7>, <LineWidth,Crosslength,LineWidth-7> 
         }
         box{
             <-Crosslength,-LineWidth,-LineWidth-7>, <Crosslength,LineWidth,LineWidth-7>
         }
         rotate z*45
         pigment{ TextColor }
         finish{ ambient 1 brilliance 0 diffuse 0}
         no_shadow
     }
 }
 
 box{
     <-OrbitA*OrbitE-3,-LineWidth,-LineWidth-7>, <0,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     no_shadow
 }
 
 box{
     <0,-LineWidth,-LineWidth-7>, <300,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate z*Angleinf
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 box{
     <0,-LineWidth,-LineWidth-7>, <300,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate -z*Angleinf
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 difference{
     torus{
         4,LineWidth
         rotate x*90
     }
     box {
         <-5,0,-5>,<5,5,5>
     }
     box {
         <-5,-5,-5>,<5,0,5>
         rotate -z*Angleinf
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     translate -z*7
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 object{
     crossBars
 }
 
 object{
     crossBars
     translate -x*OrbitA*(OrbitE-1)
 }
 
 object{
     crossBars
     translate -x*OrbitA*OrbitE
 }
 
 //Text
 text {
     ttf "timesi.ttf" "a" 1, 0
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <OrbitA*(0.5-OrbitE)-Textscale/4,Textscale/4,-7>
     no_shadow
 }
 
 union{
     text {
         ttf "timesi.ttf" "r" 1, 0
     }
     text {
         ttf "timesi.ttf" "p" 1, 0
         scale 0.5
         translate 0.2*x
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <-(EarthRadius+0.3*(OrbitA*(OrbitE-1)-EarthRadius))-Textscale/4,Textscale/4,-7>
     no_shadow
 }
 
 union{
     text {
         ttf "symbol.ttf" "u" 1, 0
         matrix 
             < 1, 0, 0,
             0.3, 1, 0,
             0, 0, 1,
             0, 0, 0 >
     }
     text {
         ttf "symbol.ttf" chr(165) 1, 0
         scale 0.5
         translate <0.6,-0.1,0>
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <-OrbitA*OrbitE-Textscale/4+9,-0.6*Textscale,-7>
     no_shadow
 }

Légendes

Ajoutez en une ligne la description de ce que représente ce fichier

Éléments décrits dans ce fichier

dépeint

type MIME

image/gif

Historique du fichier

Cliquer sur une date et heure pour voir le fichier tel qu'il était à ce moment-là.

Date et heureVignetteDimensionsUtilisateurCommentaire
actuel8 mars 2006 à 02:01Vignette pour la version du 8 mars 2006 à 02:01300 × 300 (12 kio)Brandir~commonswiki{{Information| |Description = Animation showing the motion of a small body (green) in an hyperbolic orbit around a much more massive body (blue). |Source = Own work. Rendered with ''PovRay-3.0'', animated with ''gifsicle''. |Date = Created 7. Mar. 2006.

La page suivante utilise ce fichier :

Usage global du fichier

Récupérée de « https://fr.wikibooks.org/wiki/Fichier:Hyperbolic_orbit.gif »